Zur Anbindung von Windows Vista , Windows 7 oder Windows 8 Clients an Arktur (4 - bzw. Versionen / Linux - Servern, die die Domainanmeldung mit höheren Windows-Versionen nicht unterstützen) bietet sich eine lokale Anmeldung ohne Passwort an und die darauf folgende zwangsweise Anmeldung an Arktur mit einem Script von  AutoIT - im deutschen  AutoIT-Forum findet man weitere Hilfe!

Hier mein Beispiel (Ver 0.6):
( getestet mit Windows 8 64 bit und 32 bit sowie 7 64 bit )
Verbesserungen weiter unten:   nur ein Eingabefenster - weiter mit Enter

---

;Anmeldung an Arktur4 unter Win7 oder Win8
;Compiliertes Script in den Autostart
;Es werden die Laufwerke gemappt und dabei Nutzername und Passwort "geprüft"
;Die Eingabe von Nutzernamen und Passwort wird wiederholt, bis die Anmeldung erfolgreich war
;erstellt von André Dix - HIT-Systemhaus Hohenstein-Ernstthal http://www.hit-systemhaus.de
;modifizert von Jörg Fiebig - Erzgebirgskolleg Breitenbrunn http://www.erzgebirgskolleg.org
;
;Vereinbarungen:
; erstes Netzwerklaufwerk:  ASCII-Code von H
$eNWL=ASC("H")
; letztes Netzwerklaufwerk: ASCII-Code von Z
$lNWL=ASC("Z")

; Homelaufwerksbuchstabe  U:
$LW1="U:"
; Temp T:
$LW2="T:"
; Public P:
$LW3="P:"
; Vorlagen V:
$LW4="V:"
;Servername
$Server="\\Arktur\"


$LWB=""
$un=""
$pw=""


;Das Programm :-)
_anmeldevorgang()

;Was es macht
Func _anmeldevorgang()
_trennen()
_anmelden()
_verbinden()
_beenden()
EndFunc


; Trennen der Netzwerklaufwerke vom ersten bis zum letzten - siehe Vereinbarungen
Func _trennen()
   For $LWBN=$eNWL to $lNWL
       $LWB=chr($LWBN)&":"
       DriveMapDel($LWB)
   Next
   
; oder nur die typischen Arktur Laufwerke  - dann oben auskommentieren und hier aktivieren
;DriveMapDel("T:")
;DriveMapDel("P:")
;DriveMapDel("U:")
;DriveMapDel("V:")
EndFunc

Func _anmelden()
$un = InputBox("Bitte Anmeldename eingeben","Benutzername:","", " M", 390, 130)
$pw = InputBox("Bitte Kennwort eingeben","Kennwort:","","*M", 380, 130)
; das M verhindert leere Eingaben - dahinter Breite und Höhe - wobei die Minimalhöhe 115 auch interessant wäre!
EndFunc


Func _verbinden()

DriveMapAdd($LW1, $Server&"homes", 0, $un, $pw)

If @error <> 0 then
    $FNr=@error
    Msgbox(0,"Fehler "&$FNr,"Anmeldedaten falsch!")
    _anmeldevorgang()
    exit
 else
    DriveMapAdd($LW3, $Server&"pub", 0, $un, $pw)
    DriveMapAdd($LW2, $Server&"tmp", 0, $un, $pw)
    DriveMapAdd($LW4, $Server&"vorlagen", 0, $un, $pw)
EndIf

EndFunc


Func _beenden()
Exit
EndFunc

---

Download des Scripts V0.6   (rechter Mausklick - Speichern unter)

Wem das Ganze aber mit nur einer Eingabemaske besser gefällt, der wäre mit der hier folgenden Version 0.8 gut bedient:
(Es wurde nur die anmelde - Funktion geändert)

---

Func _anmelden()

; Eingabemaske ohne Titelleistensteuerelemente
$EMaske = GUICreate("Serveranmeldung",200,58, -1, -1,0x00C00000)
$name = GUICtrlCreateInput ("Nutzername",20,2,120,22)
; Passworteingabe mit Punkten
$pass = GUICtrlCreateInput ("Passwort",20,32,120,22,0x0020)
$los = GUICtrlCreateButton ("OK",145,4,50,50)
GUISetState(@SW_SHOW)
While 1
    $msg = GuiGetMsg()
       
    If $msg = $los Then
       $un = GUICtrlRead ($name)
       $pw = GUICtrlRead ($pass)
       ExitLoop
    EndIf

WEnd
$EMaske = GUIDelete()
EndFunc

---

Download des (gesamten, korrigierten) Scripts V0.8  (rechter Mausklick - Speichern unter)

Nun ist im praktischen Einsatz aufgefellen, dass die Nutze rmeist die Enter-Taste drücken und nicht mit der Maus klicken. Das ist nun in Version 0.9 realisiert:

---

Es muss am Anfang noch eingefügt werden:

; version 0.9
; Vereinbarungen:


#include <GUIConstants.au3>
#include <ButtonConstants.au3>
#include <Date.au3>

Dann reicht in der Funktion anmelden eine kleine Änderung:

Func _anmelden()

; Eingabemaske ohne Titelleistensteuerelemente
$EMaske = GUICreate("Serveranmeldung",200,58, -1, -1,0x00C00000)
$name = GUICtrlCreateInput ("Nutzername",20,2,120,22)
; Passworteingabe mit Punkten
$pass = GUICtrlCreateInput ("Passwort",20,32,120,22,0x0020)
$los = GUICtrlCreateButton ("OK",145,4,50,50, $BS_DEFPUSHBUTTON)
GUISetState(@SW_SHOW)
While 1

---

Download des (gesamten, korrigierten) Scripts V0.11  (rechter Mausklick - Speichern unter) bei dem auch noch die Zeit mit Arktur synchronisiert wird

Sie können es sich auch hier im Quelltext ansehen.


Es wird an der Jakobus-Oberschule Mülsen eingesetzt (Win7 - 64bit, Arktur 4)
und natürlich am Erzgebirgskolleg Breitenbrunn eingesetzt (Win8.1 Pro / Enterprise - 32bit, Arktur 4).
Unter Windows 8 ist darauf zu achten, dass sie Zeit von Arktur (Server) und den Clients übereinstimmt, sonst gibt es sporadisch auftretende Netzwerkprobleme!


Download der gezippten exe (V 0.11) arkturlogin.exe  (rechter Mausklick - Speichern unter)